Adding temperature sensors to a hot water heater

/*
Hot water heater temperature monitoring station.

This reads a few temperature sensors at various points
on a hot water heater (or whatever) and transmits
them back to some place where they can be read and 
processed (like a Home Assistant system).

Temperature sensors used here are DS18B20's in non-parasite mode.
These have good temperature resolution up to hot water temperatures.
*/

#include <OneWire.h>
#include <DallasTemperature.h>

#include <ESP8266WiFi.h>
#include <ESP8266mDNS.h>
#include <PubSubClient.h>

#define wifi_ssid "Wifi SSID"
#define wifi_password "Actual password"

#define mqtt_server "dummy-mqtt-server.com"
#define mqtt_will_topic "home/status/garage"
#define mqtt_user "user"
#define mqtt_password "password"

#define ONE_WIRE_BUS D2

OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);
WiFiClientSecure  espClient;
PubSubClient client(espClient);

int numDevices;
String baseTopic = "home/garage/";
unsigned long previousMillis = 0;
const long intervalMillis = 60000; // how often to update 

DeviceAddress tempDeviceAddress; 

void setup(){
  pinMode(D2, INPUT);
  pinMode(D2, OUTPUT);
  sensors.begin();
  Serial.begin(9600);
  Serial.print("Greetings from the water heater.");
  setup_wifi();
  setup_mqtt();

  Serial.print("Initializing devices...");
  numDevices= sensors.getDeviceCount();
  Serial.print("Found ");
  Serial.print(numDevices, DEC);
  Serial.println(" devices.");

  for(int i=0;i<numDevices; i++){
    if(sensors.getAddress(tempDeviceAddress, i)){
      Serial.print("Found device ");
      Serial.print(i, DEC);
      Serial.print(" @: ");
      printAddress(tempDeviceAddress);
      Serial.println();
    } else {
      Serial.print("Found phantom device at ");
      Serial.print(i, DEC);
      Serial.print(" but could not detect address. Check power and cabling");
    }
  }
}

void loop(){ 
  unsigned long currentMillis = millis();

  if (!client.connected()) {
      reconnect();
  }
  client.loop();
  ArduinoOTA.handle();

  if (currentMillis - previousMillis >= intervalMillis) {
    previousMillis = currentMillis;
    readSensors();
  }

}

void readSensors() {
  String fullTopic;
  String value;
  String address;

  sensors.requestTemperatures();

  for(int i=0;i<numDevices; i++){
    if(sensors.getAddress(tempDeviceAddress, i)){
      address = (char *) tempDeviceAddress;
      Serial.print("Temperature @: ");
      Serial.print(i,DEC);
      float tempC = sensors.getTempC(tempDeviceAddress);
      printAddress(tempDeviceAddress);
      Serial.print(" °C: ");
      Serial.println(tempC);
      fullTopic = baseTopic + i;
      value = String(tempC);
      client.publish(fullTopic.c_str(), value.c_str(), true);
    }
  }
}

void printAddress(DeviceAddress deviceAddress) {
  for (uint8_t i = 0; i < 8; i++){
    if (deviceAddress[i] < 16) Serial.print("0");
      Serial.print(deviceAddress[i], HEX);
  }
}

void setup_wifi() {
  espClient.setInsecure();  // required since bearssl
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(wifi_ssid);
  WiFi.mode(WIFI_STA);
  WiFi.begin(wifi_ssid, wifi_password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
}

void setup_mqtt() {
    client.setServer(mqtt_server, 8883);
    client.publish(mqtt_will_topic, "1", true);
}

void reconnect() {
  int retryCount=0;
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect("Garage", mqtt_user, mqtt_password, mqtt_will_topic, 
                        1, 1, "0")) {
      Serial.println("connected");
      client.publish(mqtt_will_topic, "1", true);
      
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 3 seconds");
      delay(3000);
      retryCount++;
      if (retryCount>20) {
        Serial.println("Goofed up. Restarting.");
        ESP.restart();
      }
    }
  }
  Serial.print("MQTT connected.");
}